• 
  1. VDD=115V, 13.56MHz, Resonator loaded Q=10.
  2. VDD=40V, resonator Q=10, using Ls, Ctune for the 115V case
  3. VDD=40V, resonator Q=10, optimizing Ls, Ctune for 40V case
  

* This cicuit models the TC resonator and matching circuit in time domain
.INCLUDE irf730.cir

VIN	100	0	DC	40.0
LDD	100	1	25u IC=0

VGG	201	0	SIN(0.0 15.0 13.56meg 0 0)
RGG	201	200	2.2

XQ1     1       200    0       irf730

RDUM	1	0	100000
CDD	1	0	100p
*LS	1	2	2.5u
*For Q=10,20 VDD=115
*LS	1	2	0.800u
*For Q=10 VDD=40
LS	1	2	0.600u
CS	2	3	2700p
*For Q=10, VDD=115
*CP	3	1000	340p
*For Q=10, VDD=40
CP	3	1000	480p
*For Q=20
*CP	3	1000	280p

LP	3	1000	1u
VDUM	1000	0	0

LR	10	0	6.115u
CR	10	0	23.47p
*For Q of 10
RR	10	0	5000.

KLL	LP	LR	0.30

.OPTIONS NOPAGE RELTOL=1.0E-8
.END

.SUBCKT irf730 1 2 3
**************************************
*      Model Generated by MODPEX     *
*Copyright(c) Symmetry Design Systems*
*         All Rights Reserved        *
*    UNPUBLISHED LICENSED SOFTWARE   *
*   Contains Proprietary Information *
*      Which is The Property of      *
*     SYMMETRY OR ITS LICENSORS      *
*Commercial Use or Resale Restricted *
*   by Symmetry License Agreement    *
**************************************
* Model generated on Apr  2, 99
* MODEL FORMAT: SPICE3
* Symmetry POWER MOS Model (Version 1.0)
* External Node Designations
* Node 1 -> Drain
* Node 2 -> Gate
* Node 3 -> Source
M1 9 7 8 8 MM L=100u W=100u
* Default values used in MM:
* The voltage-dependent capacitances are
* not included. Other default values are:
*   RS=0 RD=0 LD=0 CBD=0 CBS=0 CGBO=0
.MODEL MM NMOS LEVEL=1 IS=1e-32
+VTO=3.99 LAMBDA=0.000144225 KP=2.88036
+CGSO=6.42864e-06 CGDO=1e-11
RS 8 3 0.0001
D1 3 1 MD
.MODEL MD D IS=7.93539e-09 RS=0.020221 N=1.5 BV=400
+IBV=0.00025 EG=1.2 XTI=3.05954 TT=0
+CJO=5.57785e-10 VJ=5 M=0.688789 FC=0.5
RDS 3 1 1e+06
RD 9 1 0.485778
RG 2 7 2.63633
D2 4 5 MD1
* Default values used in MD1:
*   RS=0 EG=1.11 XTI=3.0 TT=0
*   BV=infinite IBV=1mA
.MODEL MD1 D IS=1e-32 N=50
+CJO=8.85779e-10 VJ=2.49436 M=0.9 FC=1e-08
D3 0 5 MD2
* Default values used in MD2:
*   EG=1.11 XTI=3.0 TT=0 CJO=0
*   BV=infinite IBV=1mA
.MODEL MD2 D IS=1e-10 N=0.510385 RS=3e-06
RL 5 10 1
FI2 7 9 VFI2 -1
VFI2 4 0 0
EV16 10 0 9 7 1
CAP 11 10 8.85779e-10
FI1 7 9 VFI1 -1
VFI1 11 6 0
RCAP 6 10 1
D4 0 6 MD3
* Default values used in MD3:
*   EG=1.11 XTI=3.0 TT=0 CJO=0
*   RS=0 BV=infinite IBV=1mA
.MODEL MD3 D IS=1e-10 N=0.510385
.ENDS irf730

• 
  1. The series cap in the matching network is mostly for DC blocking. As long as it has a fairly low reactance, tuning can be accomplished by modifying the series coil and the primary shunt capacitor.
  2. Start off with no or little capacitance in between the MOSFET drain and ground. At 13.56MHz, the transistor Cds should be sufficient. However, if instantaneous Vds is more than 300V, add 68-100pf and see what happens.
  3. The secret to good class-E is low matching circuit Q. This means tight primary-secondary coupling for good power transfer (contrary to what many long-streamer coilers use) and as low series inductive reactance as you can get away with. This also means keeping the load-line impedance close to the expected coil primary input impedance. Resonance in a loosely coupled high-Q primary will smoke your MOSFETs (I’ve tried this)!!!
  4. Higher VDD is your friend, if Qs are low and your MOSFET can tolerate it. This also helps reduce I²R losses in the primary (lower primary current).
  5. I can’t overemphasize enough the need to shield the coil at these frequencies. Inadvertent parasitic coupling and radiation looks like extra loading to your amplifier circuit…as well as generating loads of obnoxious RFI. If it interferes with your digital camera, imagine what might be doing to shortwave-listening grannies on the other side of Oz!! ;)